MEL FAQ

• MEL スクリプトの書き方は?
• 文字列の連結とは何ですか?
• プログラムの作り方
• 変数の名前の付け方
• マニュアルの見方
• MEL スクリプトをデバッグする方法は?
  • エラーの存在する場所を調べる
    以下のメニューにチェックを入れておきます。
    Script Editor → Script → Show Line Numbers
    これによって、以下のようにエラーのある行番号が表示されるようになります。
    // Error: line 15: Cannot find procedure "sphare". //
    エラーが出たら、まず表示された行をチェックしてエラーを見つけます。 もし、その行にエラーが見つからなければ、それ以前の行をチェックしてください。
  • スクリプト中の変数の値などを調べる
    この場合は print コマンドを使用します。
    例えば、変数 $x の値を確かめたい時には、 以下のようなコマンドをチェックしたい箇所に挿入します。
    print ($x + "\n");
    スクリプトを実行すると $x の値が表示されるので、 値が正しいかどうかチェックします。
    チェックが終ったら、スクリプトから消去するか、 行の先頭に // を書き込んでコメントアウトしておいてください。
• Object's name is not unique というエラーメッセージの意味がわかりません
  このエラーメッセージは GUI のオブジェクトを、 すでに存在するオブジェクトと同じ名前で作ろうとした時に表示されます。
  例えば、以下のようなバグのあるコマンドを実行すると button コマンドの部分でエラーが表示されて実行が中止されます。

  window -title "test" window1;
  columnLayout;
  button -label "Close" -command "deleteUI window1;  // エラーがある
  showWindow;
  

  この時、window コマンドは正常に実行されて window1 という名前のウインドウが作られています。 しかし、showWindow が実行されていないので表示はされません。
  この後、エラーの部分を修正して上の同じコマンドを実行すると、 window コマンドの部分ですでに作られている window1 という名前のウインドウを作ろうとするので、 Object's name is not unique というエラーが表示されます。
  このエラーを修正するには window の名前 window1 を変えるか、 以下のコマンドによって window1 を消去します。
  deleteUI window1;
• 以下のスクリプトで Close ボタンを押してもウインドウが消えません。なぜでしょうか?

  global proc testWindow()
  {
  	$winName = `window -title "test"`;
  	columnLayout;
  	button -label "Close" -command "deleteUI $winName";
  	showWindow;
  }
  

  $winName という変数に作られたウインドウの名前を代入していますが、 この変数はプロシージャー testWindow の内部変数なので、 このプロシージャの実行が終るとともに消えてしまいます。 ですから、ボタンを押した時には deleteUI コマンドによって $winName を参照しようとしても失敗してしまいます。
  こういう場合は以下のように外部変数を使用します。

  string $winName;    // 外部変数$winName
  global proc testWindow()
  {
  	global string $winName;    // この変数は外部変数の$winName
  
  	$winName = `window -title "test"`;
  	columnLayout;
  	button -label "Close" -command "deleteUI $winName";
  	showWindow;
  }
  

  または、以下のようにウインドウの名前をコマンドの文字列へあらかじめ入れておきます。

  global proc testWindow()
  {
  	$winName = `window -title "test"`;
  	columnLayout;
  	button -label "Close" -command ("deleteUI " + $winName);
  	showWindow;
  }
  

• GUIの部品を後から追加する方法は?
  以下のように setParent を省略せずに実行してください。

  window;
  columnLayout;
  setParent ..;    // 省略しない
  showWindow;
  

  これでウインドウを表示しておいてから button コマンドなどを実行すると、 実行するたびに部品が追加されてゆきます。
• GUIにおけるテンプレートの使い方は?
  レイアウトコマンドなどでテンプレートを使用するには以下のように実行します。
  setUITemplate も参照してください。

  uiTemplate testTemplate;    // テンプレートオブジェクトを作る
  columnLayout -defineTemplate testTemplate  // そのテンプレートオブジェクトに対して定義する
  	-columnAlign right
  	-columnOffset right 10
  	-columnWidth 20
  	-rowSpacing 10;
  
  window;
  columnLayout -useTemplate testTemplate;
  button -label "test1";
  button -label "test2";
  showWindow;