最終課題

最終課題の説明

授業時間内に課題を提出してもらう。

• 必ず授業時間内に提出する。
• 完成していなくても、時間がきたら提出すること。
  〆切後(授業時間終了後)の提出は無効。
• 今回は正解でもOKは出ない。
  とりあえず、提出のみしてもらう。
• 正解であるかどうか、と同時に課題の内容(スクリプトの書き方など)もチェックする。
• 正解者のリストは、課題チェック後に「課題集計リスト」に発表する。

課題

ホームディレクトリの下のunixディレクトリに
kadai.shという名前でシェルスクリプトを作り、
画像ファイル名の前半部分と番号の種類を変換できるようにせよ。

• シェルスクリプトの実行形式
  % csh kadai.sh オプション 変更前ファイル名 変更後ファイル名

  オプション

  この部分には以下のどちらかを指定する

  -1

  0001, 0002, 0003, ... から 1, 2, 3, ... へ変換

  -4

  1, 2, 3, ... から 0001, 0002, 0003, ... へ変換

  変更前ファイル名

  変更前のファイル名の前半部分
  ファイル名の前半部分が同じファイルを全部変換すること。
  番号が何番から始まって、何番で終るかもスクリプトで調べる。
  番号が1から始まっていない場合、または途中の番号が飛んでいる場合も変換する。
  (下の実行例を参考のこと)

  変更後ファイル名

  変更後のファイル名の前半部分

• 変換するファイル名の形式
  名前.番号.iff
  番号は以下のいづれかひとつ。
  1. Frame Padding → 1
     1, 2, 3, ... 10, 11, 12 ...
  2. Frame Padding → 4
     0001, 0002, 0003, ... 0010, 0011, 0012, ...

実行例

% ls *.iff
tmp.1.iff tmp.2.iff tmp.3.iff tmp.4.iff tmp.5.iff
kadai.0006.iff kadai.0007.iff kadai.0009.iff kadai.0010.iff
% csh kadai.sh -4 tmp test
% ls *.iff
test.0001.iff test.0002.iff test.0003.iff test.0004.iff test.0005.iff
kadai.0006.iff kadai.0007.iff kadai.0009.iff kadai.0010.iff
% csh kadai.sh -1 kadai tmp
% ls *.iff
test.0001.iff test.0002.iff test.0003.iff test.0004.iff test.0005.iff
tmp.6.iff tmp.7.iff tmp.9.iff tmp.10.iff

解答例

whileを使った解答例。

4桁の番号を変換するのでwhileによって10000まで調べれば良い。

set i = 1
while($i < 10000)
	if($i < 10) then
		set n = 000$i
	else if($i < 100) then
		set n = 00$i
	else if($i < 1000) then
		set n = 0$i
	else if($i < 10000) then
		set n = $i
	endif
	if($argv[1] == -1 && -f $argv[2].$n.iff) then
		mv $argv[2].$n.iff $argv[3].$i.iff
	else if($argv[1] == -4 && -f $argv[2].$i.iff) then
		mv $argv[2].$i.iff $argv[3].$n.iff
	endif
	@ i ++
end

foreachを使った解答例。

printf コマンドを使用すると0の付いた数字を8進数として処理してしまうのでsedコマンドで最初の0を取っている。

foreach f ($argv[2].*.iff)
	set i = $f:r:e
	if($argv[1] == -1) then
		set i = `echo $i | sed 's/^00*//'`
		mv $f $argv[3].`printf "%d" $i`.iff
	else if($argv[1] == -4) then
		mv $f $argv[3].`printf "%04d" $i`.iff
	endif
end

参考にならない解答例。

find を使って1行で実行したもの。

find . -name "$argv[2].*.iff" -exec csh -c 'set f = {} ; set i = `echo $f:r:e | sed "s/^00*//"` ; set d = `echo '$argv[1]' | sed "s/-//"` ; mv $f '$argv[3]'.`printf "%0"$d"d" $i`.iff' \;