変数

変数とは何か

MEL のスクリプトにおいて計算結果の数値や文字列などを覚えさせておいて、後で使いたいときには変数というものを使います。
例えば、ある同じ数値をスクリプト中の複数の箇所で使いたい場合には、変数に数値を覚えさせておいて、数値の代わりに使うと便利です。
変数には代入という操作で数値や文字列を入れておくことができます。
変数には名前がついていて、規則にしたがう限り好きな名前でいくつでも変数を定義することができます。

MEL の変数を使うときには以下の事項を注意してください。

変数名の先頭にどんな場合も必ず $ がつきます。
変数名は英数字と_ ( アンダースコアー )で作ります。
先頭の文字は英字または、_ ( アンダースコアー )です。先頭に数字は使えません。
大文字・小文字の区別があります。ですから、$a1 と $A1 は別の変数です。
(正しい変数名の例)
$x1, $xRes, $y_val, $_name
(間違った変数名の例)
$123, $5test, $xx-yy
変数に代入するときには代入演算子 = (イコール)を使います。
(例)
$x1 = 2;
$xRes = 640;
$y_val = 2.5;
変数には型があります。
型とは変数の種類のことです、。
何かを変数に代入したい場合には、同じ型の変数に代入する必要があります。 (ただし、例外があります)
型の種類は以下の通りです。

int
整数
-256, -2, 0, 1, 2, 1024, 32694 などです。
float
浮動小数点数
-2.6, 0.002, 16.0, 512.666 などの小数点のついた数です。
string
文字列
"abcedfg", "123456", "MEL script" などです。
このように " (ダブルクォート)で囲まれたものは文字列になります。
ただし、" (ダブルクォート)で囲まれていなくても文字列だと見なされる場合もあります。
上の例で "123456" は 1 や 2 などの文字が並んでいるものであって、数値(整数)の 123456 ではないことに注意してください。
vector
3 つの浮動小数点数を 1 つにまとめたもの
3 次元座標や色の値を表すのに使われます。
matrix
浮動小数点数の行列
浮動小数点数がたて・よこにいくつか並んでいるものです。

(例)
変数宣言をしていない変数に、整数を代入すると、その変数は int の型の変数、浮動小数点数を代入すると、その変数は float の型の変数になり、文字列を代入すると、その変数は string の型の変数になります。
$x = 3; ← $x は int 型の変数になる
$y = 2.5; ← $y は float 型の変数になる
$z = "test"; ← $z は string 型の変数になる
変数宣言があります。
変数宣言とは変数が何の型かをあらかじめ定義しておくものです。
変数宣言はしなくてもエラーにはなりません。
しかし、なるべく変数宣言をしておく方がスクリプトの内容が理解しやすくなりますし、実行速度も速くなります。
(例)
int $x; ← $x は int であるという変数宣言
float $y; ← $y は float であるという変数宣言
string $s; ← $s は string であるという変数宣言
変数宣言はプロシージャーの途中でおこなうこともできます。 global proc test2() { int $x; $x = 1; float $y = 3.5; ← $y は float であるという変数宣言をして同時に 3.5 を代入している }
配列があります。
配列は複数の変数をまとめて、ひとつの名前をつけたものです。
配列を使うことによって同じ名前で複数の値を代入できます。
ただし、同じ配列には同一の型のものしか代入できません。
配列も変数宣言無しで使えますが、宣言をしておいた方が少し処理速度が速くなります。
(例)
int $xx[2]; ← $xx は配列で個数は 2 つ
float $yy[]; ← $yy は配列で個数は未定
float $zz[] = {5.2, 6.1, 7.8}; ← 配列の初期化はC言語と同じ
$xx[0] = 1; ← $x xの 0 番目に 1 を代入
$xx[1] = 2; ← $xx の 1 番目に 2 を代入
$yy[0] = 3.5; ← $yy[0] が作られて 3.5 が代入される
$yy[1] = 0.3; ← $yy[1] が作られて 0.3 が代入される
$yy[3] = 5.6; ← $yy[2] をとばして $yy[3] に代入可能($yy[2] は自動的に 0)
外部変数とローカル変数の区別があります。
プロシージャの { から } で囲まれた部分で宣言された変数はローカル変数になり、それ以外の、プロシージャーの外部で定義された変数は外部変数になります。
外部変数はどのプロシージャーからでも共通に使用することができます。ただし、外部変数をプロシージャー内部で使用する時は global をつけて変数宣言する必要があります。
(例)
以下の例で、test3() と test4 の実行が終った時点で、外部変数の $x1 の値は 1 になっています。
```
int $x1;            ← 外部変数 $x1 の宣言
global proc test3()
{
	global int $x1;     ← 外部変数 $x1 を test3() 内で使う変数宣言
	$x1 = 1;    ← 外部変数の $x1 
}
global proc test4()
{
	int $x1;    ← ローカル変数 $x1 の宣言
	$x1 = 2;    ← ローカル変数の $x1 
}
test3();
test4();
```
外部変数の型は Maya を終了するまで変更できません。
外部変数は一度変数宣言をすると型を後から変更できなくなります。
int $v1;
float $v2;
float $v1; ← $v1 は int で宣言されていたのでエラー
変数を使った計算には算術演算子を使います。
算術演算子とは以下のような数値の計算に使う記号のことです。
算術演算子を使った計算結果は型によって違うことに注意してください。
以下に int と float で使用される算術演算子をあげます。
その他の型については後ほど述べることにします。

+
加算
-
減算
*
乗算
/
除算
+=
計算結果を変数に加算して代入
-=
計算結果を変数に減算して代入
*=
計算結果を変数に乗算して代入
/=
計算結果を変数に除算して代入
%=
計算結果で変数を除算した余りを代入
++
変数の内容に 1 を加算
--
変数の内容に 1 を減算
%
剰余
左の数を右の数で乗算したときの余りを求める演算子です。
演算は ( ) によってグループ化されます。
変数はプロシージャーの引数にも使うことができます。
下の変数の例を参照してください。

以下に C 言語の知識がある人のために C 言語との違いをあげておきます。

int、float はC言語と同じです。
double、char、short などはありません。
string、vector、matrix という独自の型があります。
配列は C 言語と違い、宣言時に個数の指定は必要ありません。
構造体はありません。
ポインターもありません。
#include, #define などはありません。

変数の例

半径を 1 づつ小さくしながら 3 個の球を接しながら並べる MEL スクリプトをプロシージャーと変数を使って作ってみましょう。
プロシージャーの引数(int $r)に 1 個目の球の半径を与えて実行すると、2 番目以降の球は半径が 1 づつ小さくなって作られてゆくようにします。

make3Sphere1.mel というファイル名の MEL スクリプトを以下の内容でエディタ(vi)によって作ります。


global proc make3Sphere1(int $r)
{
	int $m;

	sphere;
	scale $r $r $r;

	sphere;
	$r -= 1;
	scale $r $r $r;
	$m = 2 * $r + 1;
	move $m 0 0;

	sphere;
	$r -= 1;
	scale $r $r $r;
	$m += 2 * $r + 1;
	move $m 0 0;
}

Script Editor の File → Source Script によって make3Sphere.mel を読み込みます。
Script Editor のインプットウインドウに make3Sphere1(3) と打ち込んで実行します。
下図のような半径 3、2、1 の 3 個の球が作られます。
さらに make3Sphere1(4) や make3Sphere1(5) などを実行してどのような結果になるか試してみましょう。
(注意)
実行前にシーンの中のオブジェクトを消去または移動してから実行しないとオブジェクトが重なって見にくいかもしれません。

スクリプトの解説

global proc make3Sphere(int $r): int の引数($r)を 1 個とるプロシージャーの宣言です。
$r は最初の球の半径になります。
プロシージャーに引数をつけることによってプロシージャーの中の数値をいちいち書き換えなくても球の半径を変更して実行することができるようになります。
このプロシージャでは $r の値が 3 未満だと、マイナスの半径の球ができてしまうことに注意して下さい。
int $m;: 球を移動するための値を入れておく変数。
sphere;: 1個目の球を作ります。
scale $r $r $r;: 1個目の球の半径は $r なので球を $r だけスケールします。
sphere;: 2個目の球を作ります。
$r -= 1;: 2 個目の球の半径は 1 個目より 1 小さいので $r から 1 を引いておきます。
scale $r $r $r;: 2個目の球を $r だけスケールします。
1個目の球よりも1だけ小さい半径になります。
$m = 2 * $r + 1;: 2個目の球を移動する距離を求める計算式です。
$r は 2 行前の計算($r -= 1;)によって 1 個目の球の時より 1 だけ小さくなっているので、ここの時点で 1 個目の球の半径は $r + 1 になります。
それと 2 個目の球の半径($r)を加えれば 2 つの球の間の距離になります。
$m = ($r + 1) + $r
この式をまとめて以下のようになります。
$m = 2 * $r + 1
move $m 0 0;: 2 個目の球を X 軸方向に $m だけ移動します。
sphere;: 3 個目の球を作ります。
$r -= 1;: 3 個目の球の半径は 2 個目より 1 小さいので $r から 1 引きます。
scale $r $r $r;: 3 個目の球を $r だけスケールします。
$m += 2 * $r + 1;: 3 個目の球を移動する距離を求める計算式です。
2 個目と 3 個目の球の距離の計算方法は 1 個目と 2 個目の場合と同じになります。
この時点で、$m にはすでに 2 個目までの距離が入っているので、それに 2 個目と 3 個目の距離を加えれば良いでしょう。
$m = $m + ($r + 1) + $r
右辺をまとめます。
$m = $m + 2 * $r + 1
+= で式を簡単にします。
$m += 2 * $r + 1
move $m 0 0;: 3 個目の球を X 軸方向に $m だけ移動します。

練習

上の make3Sphere1.mel を参考にして、5 個の球がでる make5Sphere1.mel というMEL スクリプトを作ってみましょう。
例えば、make5Sphere1(5) と打ち込んで実行すると、半径 5、4、3、2、1の球が作られるようにします。
make5Sphere1.mel を参考に make5Sphere2.mel を作り、半径が 1 づつ大きくなってゆくように書き換えてみましょう。
例えば、make5Sphere2(2) などと実行すると最初に半径 2、3、4、5、6の球が作られるようにします。

まとめ

変数名の先頭には必ず $ がつきます。
変数名は英数字と _ (アンダースコア)で作られます。
変数名には型があります。
変数の計算には各種の演算子を使用します。
変数にはローカル変数と外部変数の違いがあります。

練習課題

参考

MAYA
Maya, MEL 関係(Tips, FAQ, コマンド)のページ
ベクトル
MAYA関係のサイト

Prev | Next
Home | Contents

Mail