Render Node Utilities (Triple Switch)

tripleSwitch

マテリアルの色のような、 3 つの数値によって構成されるアトリビュートをオブジェクトごとに切替えるには tripleSwitch を使用します。

tripleSwitch の例

2 つの NURBS の球を作成して lambert マテリアルをアサインし、 そのマテリアルに対し、オブジェクトごとに違うテクスチャーをアサインするスクリプトです。

1. 以下の MEL スクリプトを tripleSwitch1.mel という名前で作ります。

   global proc tripleSwitch1()
   {
   	string $spname1[] = `sphere`;
   	string $spname2[] = `sphere`;
   	move 2 0 0;
   
   	string $sname = `shadingNode -asShader lambert`;
   	string $sgname = `sets -renderable true -noSurfaceShader true -empty`;
   	connectAttr -f ($sname + ".outColor") ($sgname + ".surfaceShader");
   
   	select -r $spname1[0] $spname2[0];
   	sets -e -forceElement $sgname;
   
   	string $tsname = `shadingNode -asUtility tripleShadingSwitch`;
   	connectAttr -f ($tsname + ".output") ($sname + ".color");
   
   	string $sphname[] = `listRelatives -s $spname1[0]`;
   	connectAttr ($sphname[0] + ".instObjGroups[0]") ($tsname + ".input[0].inShape");
   	$sphname = `listRelatives -s $spname2[0]`;
   	connectAttr ($sphname[0] + ".instObjGroups[0]") ($tsname + ".input[1].inShape");
   
   	string $txname1 = `shadingNode -asTexture fractal`;
   	string $plname1 = `shadingNode -asUtility place2dTexture`;
   	connectAttr ($plname1 + ".outUV") ($txname1 + ".uv");
   	connectAttr ($plname1 + ".outUvFilterSize") ($txname1 + ".uvFilterSize");
   	connectAttr -f ($txname1 + ".outColor") ($tsname + ".input[0].inTriple");
   
   	string $txname2 = `shadingNode -asTexture noise`;
   	string $plname2 = `shadingNode -asUtility place2dTexture`;
   	connectAttr ($plname2 + ".outUV") ($txname2 + ".uv");
   	connectAttr ($plname2 + ".outUvFilterSize") ($txname2 + ".uvFilterSize");
   	connectAttr -f ($txname2 + ".outColor") ($tsname + ".input[1].inTriple");
   }
   

2. Script Editor の File → Source Script によって tripleSwitch1.mel を読み込みます。
3. Script Editor のインプットウインドウで、tripleSwitch1() を実行します。
   (tripleSwitch1() 実行後の図)
   
   (tripleSwitch1() 実行後の HyperShade の図)
   
4. レンダリングを実行します。
   それぞれの球に違うテクスチャーがアサインされています。
   

スクリプトの解説

global proc tripleSwitch1()

tripleSwitch1() というプロシージャを宣言します。

string $spname1[] = `sphere`;

1 つ目の NURBS の球を作成します。

string $spname2[] = `sphere`;

2 つ目の NURBS の球を作成します。

move 2 0 0;

2 つ目の NURBS の球を (2, 0, 0) に移動します。

string $sname = `shadingNode -asShader lambert`;

lambert マテリアルを作成します。

string $sgname = `sets -renderable true -noSurfaceShader true -empty`;

オブジェクトをマテリアルにアサインするためのセットを作ります。

-renderable true

作られたセットはシェーディンググループになって、 renderPartition ノードにコネクトされます。

-noSurfaceShader true

デフォールトのマテリアルにコネクトしません。
上で作ったマテリアル $sname にコネクトするからです。

-empty

空のセットを作ります。
セレクトされているオブジェクトがあっても、 このセットに加えないようにします。

connectAttr -f ($sname + ".outColor") ($sgname + ".surfaceShader");

マテリアルの色情報を表す outColor アトリビュートを、 セットの surfaceShader アトリビュートにコネクトします。
これで、マテリアル $sname がレンダリング可能になります。

select -r $spname1[0] $spname2[0];

作成しておいた 2 つの球をセレクトします。

sets -e -forceElement $sgname;

セレクトした 2 つの球を、作成しておいた lambert マテリアルにアサインします。

string $tsname = `shadingNode -asUtility tripleShadingSwitch`;

tripleSwitch (tripleShadingSwitch)を作成します。

connectAttr -f ($tsname + ".output") ($sname + ".color");

tripleSwitch ($tsname)の output アトリビュートを lambert マテリアル($sname)の color アトリビュートにコネクトします。

string $sphname[] = `listRelatives -s $spname1[0]`;

1 つ目の球のシェープノードの名前を求めて文字列変数 $sphname に代入します。

connectAttr ($sphname[0] + ".instObjGroups[0]") ($tsname + ".input[0].inShape");

1 つ目の球のシェープノード ($sphname)のアトリビュート instObjGroups[0] を tripleSwitch ($tsname)のアトリビュート input[0].inShape とコネクトします。

$sphname = `listRelatives -s $spname2[0]`;

2 つ目の球のシェープノードの名前を求めて文字列変数 $sphname に代入します。

connectAttr ($sphname[0] + ".instObjGroups[0]") ($tsname + ".input[1].inShape");

2 つ目の球のシェープノード ($sphname)のアトリビュート instObjGroups[0] を tripleSwitch ($dsname)のアトリビュート input[1].inShape とコネクトします。

string $txname1 = `shadingNode -asTexture fractal`;

fractal テクスチャーを作成します。

string $plname1 = `shadingNode -asUtility place2dTexture`;

fractal テクスチャーのために place2dTexture を作成します。

connectAttr ($plname1 + ".outUV") ($txname1 + ".uv");

place2dTexture ($plname1)のアトリビュート outUV を fractal テクスチャー($txname1)のアトリビュート uv にコネクトします。

connectAttr ($plname1 + ".outUvFilterSize") ($txname1 + ".uvFilterSize");

place2dTexture ($plname1)のアトリビュート outUvFilterSize を fractal テクスチャー($txname1)のアトリビュート uvFilterSize にコネクトします。

connectAttr -f ($txname1 + ".outColor") ($tsname + ".input[0].inTriple");

fractal テクスチャー($txname1)のアトリビュート outColor を tripleSwitch ($tsname)のアトリビュート input[0].inTriple にコネクトします。

string $txname2 = `shadingNode -asTexture noise`;

noise テクスチャーを作成します。
以下は、 fractal テクスチャーに対して行なった操作と同じです。

string $plname2 = `shadingNode -asUtility place2dTexture`;

noise テクスチャーのために place2dTexture を作成します。

connectAttr ($plname2 + ".outUV") ($txname2 + ".uv");

place2dTexture ($plname2)のアトリビュート outUV を noise テクスチャー($txname2)のアトリビュート uv にコネクトします。

connectAttr ($plname2 + ".outUvFilterSize") ($txname2 + ".uvFilterSize");

place2dTexture ($plname2)のアトリビュート outUvFilterSize を noise テクスチャー($txname2)のアトリビュート uvFilterSize にコネクトします。

connectAttr -f ($txname2 + ".outColor") ($tsname + ".input[1].inTriple");

noise テクスチャー($txname2)のアトリビュート outColor を tripleSwitch ($tsname)のアトリビュート input[1].inTriple にコネクトします。

練習

• 使用例の tripleSwitch1.mel を参考にして tripleSwitch2.mel を作り、 セレクトされているオブジェクトすべてに対し、 tripleSwitch によって fractal テクスチャーと noise テクスチャーが交互にアサインされるようにしてみましょう。
  (実行例)
  1. 適当にオブジェクトを作成し、セレクトしておきます。
     
  2. Script Editor のインプットウインドウで、tripleSwitch2() を実行します。
     (tripleSwitch2() 実行後の HyperShade の図)
     
  3. レンダリングを実行します。
     (レンダリング実行後の図)
     
  (ヒント)
  • sphere と move コマンドは削除します。

    	string $spname1[] = `sphere`;
    	string $spname2[] = `sphere`;
    	move 2 0 0;
    

  • そのかわりに ls -sl コマンドを実行します。

    	string $slname[] = `ls -sl`;
    

  • ls -sl コマンドの実行結果を代入した変数を使って、 select コマンドを実行します。

    	select $slname;
    

  • listRelatives 以下のコマンドを for 文で囲みます。

    	for($obj in $slname)
    	{
    	}
    

  • 以下のコマンドを削除します。

    	$sphname = `listRelatives -s $spname2[0]`;
    	connectAttr ($sphname[0] + ".instObjGroups[0]") ($tsname + ".input[1].inShape");
    

  • int の変数を for 文の前で宣言して、input のかっこの中の数字として使います。

    	int $i = 0;
    	for($obj in $slname)
    	{
    		.
    		.
    		connectAttr ($sphname[0] + ".instObjGroups[0]") ($tsname + ".input["+$i+"].inShape");
    		.
    		.
    		$i++;
    	}
    

  • 奇数番目と偶数番目で fractal と noise テクスチャーを交互にアサインします。

    	if(奇数か偶数か調べる)
    	{
    		string $txname1 = `shadingNode -asTexture fractal`;
    		string $plname1 = `shadingNode -asUtility place2dTexture`;
    		connectAttr ($plname1 + ".outUV") ($txname1 + ".uv");
    		connectAttr ($plname1 + ".outUvFilterSize") ($txname1 + ".uvFilterSize");
    		connectAttr -f ($txname1 + ".outColor") ($tsname + ".input["+$i+"].inTriple");
    	}
    	else
    	{
    		string $txname2 = `shadingNode -asTexture noise`;
    		string $plname2 = `shadingNode -asUtility place2dTexture`;
    		connectAttr ($plname2 + ".outUV") ($txname2 + ".uv");
    		connectAttr ($plname2 + ".outUvFilterSize") ($txname2 + ".uvFilterSize");
    		connectAttr -f ($txname2 + ".outColor") ($tsname + ".input["+$i+"].inTriple");
    	}
    

  • $i % 2 の結果が 0 なら $i は偶数、1 なら奇数になります。

練習課題

参考

• Maya
  Maya, MEL, Maya関係のコマンドなどのページ。