シェルスクリプトの制御構造(while, foreach)

while

シェルでもC言語のようなwhile文が使用できる。
シェルで使用するwhile文の形式は次の通り。

while(条件)
    コマンド
end

C言語の { と } は無くて、そのかわり end が最期につく。
条件は if で紹介した条件と同じである。

コマンドラインからwhileを色々と試してみる。

# ls
test1.c test2.c test3.c   <- 最初test*.cというファイルがある
# set i = 1
# while($i <= 3)    <- iが3になるまで繰り返す
while?  mv test$i.c kadai$i.c   <- ファイル名を変える
while?  @ i ++   <- iに1加える
while?  end   <- whileの終り
# ls
kadai1.c kadai2.c kadai3.c   <- ファイル名がkadaiに変っている
#

同じものをシェルスクリプトにしてみよう。
viで以下のシェルスクリプトをrename.shという名前を作る。

set i = 1
while($i <= 3)
	mv test$i.c kadai$i.c
	@ i ++
end

# ls
test1.c test2.c test3.c
# vi rename.sh
# csh rename.sh
# ls
rename.sh kadai1.c kadai2.c kadai3.c
#

foreach

シェルではC言語には無い、foreach というループが使用できる。
特定の名前のファイルなどに対してコマンドを実行する場合などに便利である。
foreachではリストの中の要素を一つづつ変数に代入してコマンドを実行する。
リストの部分にはファイル名、変数(配列)やコマンドの結果(コマンド置換)などが使用できる。

foreach 変数 ( リスト )
    コマンド
end

foreachの使用例

下の例ではC言語のプログラムを別の名前でコピーしている。

# ls
kadai.c test.c tmp.c
# foreach f (*.c)    <- *.cというファイル名を順番に変数fに代入する
foreach?  cp $f $f.old    <- $fに入っているファイル名に.oldをつけてコピー
foreach?  end    <- foreach 終り
# ls
kadai.c kadai.c.old test.c test.c.old tmp.c tmp.c.old
#

上のforeachでは以下の様に処理が進む。

1. foreach f (*.c)はforeach f (kadai.c test.c tmp.c)と展開される。
2. foreachによってset f = kadai.cが実行される。
3. cp $f $f.oldによって cp kadai.c kadai.c.oldが実行される。
4. foreachによってset f = test.cが実行される。
5. cp $f $f.oldによって cp test.c test.c.oldが実行される。
6. foreachによってset f = tmp.cが実行される。
7. cp $f $f.oldによって cp tmp.c tmp.c.oldが実行される。

• 上のforeachを使ったシェルスクリプトで、もしすでに同じファイル名のファイルがあった場合は違う名前でコピーするシェルスクリプト(cpold.sh)を作ってみよう。
  例えば、kadai.c.old1がすでに存在している場合は、kadai.cをkadai.c.old2という名前でコピーする。 さらに、kadai.c.old2もすでに存在している場合は、kadai.cをkadai.c.old3という名前でコピーする。

  # ls
  kadai.c test.c
  # vi cpold.sh
  # csh cpold.sh test.c
  # ls
  cpold.sh kadai.c test.c test.c.old1
  # csh cpold.sh test.c
  # ls
  cpold.sh kadai.c test.c test.c.old1 test.c.old2
  # csh cpold.sh *.c
  # ls
  cpold.sh kadai.c kadai.c.old1 test.c test.c.old1 test.c.old2 test.c.old3
  #
  

  上のように実行できるようにするためには、以下の様なシェルスクリプト(cpold.sh)を作る。

  foreach f ($argv)
  	set i = 1
  	while(1)
  		if(! -f $f.old$i) then
  			cp $f $f.old$i
  			break
  		endif
  		@ i ++
  	end
  end
  

まとめ

• シェルで繰り返しコマンドを実行するためにはwhileを使う。
• あるリストの要素ごとにコマンドを実行するためにはforeachを使う。

参考

• Cシェル
• Cシェルの参考書
• 「続・たのしいUNIX」 p.102 ~ p.106