変数

MELにおける変数

MELの変数はC言語の変数に似たところがある。
しかし、全てにおいてが同じわけではないので注意が必要である。

MELの変数には以下の特徴がある。

変数名の先頭にどんな場合も必ず $ がつく。
(例) $x, $val
変数名は英数字と_ ( アンダースコアー )で作る。
先頭の文字は英字。
大文字・小文字の区別あり。
(例) $x1, $xRes, $y_val

型がある。

int、float はC言語と同じ。
double、char、short などは無い。
string、vector、matrix という独自の型がある。

(例)

int $x;
float $y, $z;
string $s = "test";  ← $s は文字列型 (C言語なら char *s = "test";)

変数宣言あり。
変数宣言をすることもできるが、宣言無しでいきなり使うこともできる。
しかし、なるべく変数宣言をしておく方が安全である。

global proc test1()
{
	int $x;
	float $y = 3.5;
	$x = 1;
	$z1 = 5;      ← $z1 は自動的に int になる
	$z2 = 2.3;    ← $z2 は自動的に float になる
}

プロシージャーの途中で変数宣言することもできる。

	global proc test2()
{
	int $x;
	$x = 1;
	float $y = 3.5;
}

配列あり。
C言語と違い宣言時に個数の指定はしなくても良い。
しかし、宣言をしておいた方が少し処理速度が速くなる。
(例)

	int $xx[2];
float $yy[];    ← $y は配列で個数は未定
float $zz[] = {5.2, 6.1, 7.8};    ← 配列の初期化はC言語と同じ
$xx[0] = 1;
$xx[1] = 2;
$yy[0] = 3.5;    ← $yy[0] が作られて 3.5 が代入される
$yy[1] = 0.3;    ← $yy[1] が作られて 0.3 が代入される
$yy[3] = 5.6;    ← $yy[2] をとばして $yy[3] に代入可能($yy[2] は自動的に 0)

外部変数とローカル変数の区別あり。
プロシージャの中で定義された変数はローカル変数。
外で定義された変数は外部変数。
外部変数をプロシージャー内部で使用する時は global をつけて変数宣言する必要が有る。
(例)

	int $x1;            ← 外部変数 $x1 の宣言
global proc test3()
{
	global int $x1;     ← 外部変数 $x1 を test3() 内で使う変数宣言
	$x1 = 1;    ← test3() の外部で宣言されていた $x1 
}
global proc test4()
{
	int $x1;    ← ローカル変数 $x1 の宣言
	$x1 = 2;    ← test4() の内部で宣言された $x1 
}

外部変数の型は Maya を終了するまで変更できない。
外部変数は一度、変数宣言すると型を後から変更できなくなる。

	int $v1;
float $v2;
float $v1;    ← $v1 は int なのでエラー

構造体は無し。
ポインターも無し。
変数を使った演算は +、-、*、/、+=、-=、*=、/=、++、--、%、() などC言語と同じものを使うことができる。
% は float でも使うことができる。
sin、cos なども使える。(#include <math.h>などは必要無し)
プロシージャーの引数にも使うことができる。
使い方はC言語と似ている。
下の例を参照のこと。

変数の例

半径を1づつ小さくしながら3個の球を接しながら並べる MELスクリプトをプロシージャーと変数を使って作ってみよう。
プロシージャーの引数(int $r)に1個目の球の半径を与えて実行すると、2番目以降の球は半径が1づつ小さくなって作られてゆく。

mel ディレクトリへ移動しておく。
```
% cd mel
% pwd
/amt/home0/ad020000/mel
```

make3Sphere1.mel というファイルを以下の内容で vi によって作る。

global proc make3Sphere1(int $r)
{
	int $m;

	sphere;
	scale $r $r $r;

	sphere;
	$r -= 1;
	scale $r $r $r;
	$m = 2 * $r + 1;
	move $m 0 0;

	sphere;
	$r -= 1;
	scale $r $r $r;
	$m += 2 * $r + 1;
	move $m 0 0;
}

Script Editor の File → Source Script によって make3Sphere.mel を読み込む。
Script Editor に make3Sphere1(3) と打ち込んで実行する。
または make3Sphere1 3 と打ち込んで実行しても良い。
下図のような半径3、2、1の3個の球が作られる。
さらに make3Sphere1(4) や make3Sphere1(5) などと実行してどのような結果になるか試してみよう。
(実行前にシーンの中のオブジェクトを消去または移動してから実行しないとオブジェクトが重なって見にくいかもしれない)

スクリプトの解説

global proc make3Sphere(int $r): intの引数($r)を1個とるプロシージャー。
$r は最初の球の半径になる。
int $m;: 球を移動するための値を入れておく変数。
sphere;: 1個目の球を作る。
scale $r $r $r;: 1個目の球の半径は $r なので球を $r だけスケールする。
sphere;: 2個目の球を作る。
$r -= 1;: 2個目の球の半径は1個目より1小さいので $r から1を引く。
scale $r $r $r;: 2個目の球を $r だけスケールする。
1個目の球よりも1だけ小さい半径になる。
$m = 2 * $r + 1;: 2個目の球を移動する距離を求める。
$r は2行前の計算($r -= 1;)によって1個目の球の時より1だけ小さくなっているので 1個目の球の半径は $r + 1 である。
それと2個目の球の半径($r)を加えれば2つの球の間の距離になる。
$m = ($r + 1) + $r
↓
$m = 2 * $r + 1
move $m 0 0;: 2個目の球をX軸方向に $m だけ移動する。
sphere;: 3個目の球を作る。
$r -= 1;: 3個目の球の半径は2個目より1小さいので $r から1引く。
scale $r $r $r;: 3個目の球を $r だけスケールする。
$m += 2 * $r + 1;: 3個目の球を移動する距離を求める。
2個目と3個目の球の距離の計算方法は1個目と2個目の場合と同じである。
$mにはすでに2個目までの距離が入っているので、それに2個目と3個目の距離を加えれば良い。
$m = $m + ($r + 1) + $r
↓
$m = $m + 2 * $r + 1
↓
$m += 2 * $r + 1
move $m 0 0;: 3個目の球をX軸方向に $m だけ移動する。

練習

上の make3Sphere1.mel を参考にして、5個の球がでる make5Sphere1.mel というMELスクリプトを作ってみよう。
例えば、make5Sphere1(5) と打ち込んで実行すると、半径5、4、3、2、1の球が作られるようにする。
make5Sphere1.mel を参考に make5Sphere2.mel を作り、半径が1づつ大きくなってゆくように書き換えてみよう。
例えば、make5Sphere2(2) などと実行すると最初に半径2、3、4、5、6の球が作られるようにする。

まとめ

MELの変数名の先頭には必ず $ がつく。
MELの変数の使用方法・計算方法はC言語に似ている。
しかし、相違点もあるので注意が必要である。

練習課題

参考

Prev
Home | Contents

abe@injapan.net