MELの応用2 (岩石)

岩石を作る 2

前回のスクリプトを少し改良して岩・石を自動生成するスクリプトを作ってみる。
(ポリゴンの分割数を変えて、最後にスムースをかけている。)

岩石を作るプログラム2

まず、1個岩石を作るスクリプトを作ってみる。

以下のプロシージャをmakeRock4.melと言う名前でファイルに書き込む。


global proc makeRock4()
{
	string $poly[] = `polySphere -subdivisionsX 5 -subdivisionsY 5`;
	$x = rand(1, 2);
	$y = rand(1, 2);
	$z = rand(1, 2);
	scale $x $y $z;
	string $ver[] = `polyListComponentConversion -toVertex $poly[0]`;
	string $verE[] = `filterExpand -selectionMask 31 $ver`;
	for($obj in $verE)
	{
		select -r $obj;
		$x = rand(-0.2, 0.2);
		$y = rand(-0.2, 0.2);
		$z = rand(-0.2, 0.2);
		move -r $x $y $z;
	}
	string $polyS[] = `listRelatives -shapes $poly[0]`;
	polySmooth -divisions 2 -continuity 0.5 $polyS[0];
}

File -> Source Script でmakeRock4.melを読み込む。
Script Editor で以下のコマンドを実行してみる。
makeRock4();

string $poly[] = `polySphere -subdivisionsX 5 -subdivisionsY 5`; ポリゴンの球を作る。
$polyに球の名前が入る。 (poly[0]にtransformノード、poly[1]にpolySphereノード)

-subdivisionsX
横方向の分割数
-subdivisionsY
縦方向の分割数
$x = rand(1.0, 2.0); 乱数の値(1.0から2.0)を$xに代入。
$y = rand(1.0, 2.0); 乱数の値(1.0から2.0)を$yに代入。
$z = rand(1.0, 2.0); 乱数の値(1.0から2.0)を$zに代入。
scale $x $y $z; ポリゴンの球にスケールをかける。
string $ver[] = `polyListComponentConversion -toVertex $poly[0]`; ポリゴンの球から頂点を取り出して$ver[]に代入。
polyListComponentConversionコマンドはポリゴンのオブジェクトから頂点・フェース・エッジ・UVなどを取り出すために使用する。
返り値($ver[]に入る)はコンポーネントなので以下のfilterExpandで中身を取り出す必要がある。
string $verE[] = `filterExpand -selectionMask 31 $ver`; $verの中から頂点(31で表される)を配列に展開して$verE[]に代入。
for($obj in $verE) $verE[]から、ひとつづつ頂点を取り出して$objに代入してループの中の処理を行なう。
select -r $obj; $obj(頂点)だけをセレクトする。
$x = rand(-0.2, 0.2); 乱数の値(-0.2から0.2)を$xに代入。
$y = rand(-0.2, 0.2); 乱数の値(-0.2から0.2)を$yに代入。
$z = rand(-0.2, 0.2); 乱数の値(-0.2から0.2)を$zに代入。
move -r $x $y $z; セレクトされている頂点を、その位置から$x, $y, $zだけ移動する。
string $polyS[] = `listRelatives -shapes $poly[0]`; ポリゴンのトランスフォームノードの子ノードからシェープノード(メッシュ)を得る。
以下でポリゴンにスムースをかけるのに必要である。
polySmooth -divisions 2 -continuity 0.5 $polyS[0]; ポリゴンメッシュにスムースをかける。

-divisions
何回再帰的にスムースをかけるか。
デフォールトは1
-continuity
スムースの度合を表す。値が大きい程スムースになる。 (0.0 ～ 1.0)
デフォールトは1.0

練習

上の makeRock4.melを参考にしてmakeRock5.melを作り、岩石の個数と、岩石が作られる範囲を指定できるようにしてみよう。
(使用例)
makeRock5.melを読み込んで、makeRock5(5, 10.0, 12.0, 7.0)と実行すると5個の岩石が、X方向に-10.0から10.0まで、Y方向に-12.0から12.0まで、Z方向に-7.0から7.0までの範囲でランダムな位置に作られる。

参考

練習課題

Prev | Next
Home | Contents

abe@injapan.net