MELの応用3 (岩石)

岩石を作る 3

前回までとは違う方法で岩・石を自動生成するスクリプトを作ってみる。
今回のスクリプトは水晶のような形の岩・石を作るものである。

岩石を作るプログラム2

まず、1個岩石を作るスクリプトを作ってみる。

以下のプロシージャをmakeRock7.melと言う名前でファイルに書き込む。


global proc makeRock7()
{
	string $poly[] = `polyCylinder -radius 1.0 -height 2.0 -subdivisionsX 6 -subdivisionsY 1 -subdivisionsZ 1`;
	string $ver[] = `polyListComponentConversion -toVertex $poly[0]`;
	string $verE[] = `filterExpand -selectionMask 31 $ver`;
	for($i = 0; $i < 6; $i++)
	{
		select -r $verE[$i];
		$x = rand(-0.2, 0.2);
		$z = rand(-0.2, 0.2);
		move -r $x 0 $z;
	}
	for($i = 6; $i < 12; $i++)
	{
		select -r $verE[$i];
		$y = rand(-0.3, 0.3);
		move -r 0 $y 0;
	}
	select -r $verE[13];
	$y = rand(0.5, 1.0);
	move -r 0 $y 0;
}

File -> Source Script でmakeRock7.melを読み込む。
Script Editor で以下のコマンドを実行してみる。
makeRock7();

string $poly[] = `polyCylinder -radius 1.0 -height 2.0 -subdivisionsX 6 -subdivisionsY 1 -subdivisionsZ 1`; ポリゴンのシリンダーを作る。
$polyに球の名前が入る。 (poly[0]にtransformノード、poly[1]にpolyCylinderノード)

-radius
シリンダーの半径
-height
シリンダーの高さ
-subdivisionsX
X方向の分割数
-subdivisionsY
Y方向の分割数
-subdivisionsZ
Z方向の分割数
string $ver[] = `polyListComponentConversion -toVertex $poly[0]`; ポリゴンの球から頂点を取り出して$ver[]に代入。
polyListComponentConversionコマンドはポリゴンのオブジェクトから頂点・フェース・エッジ・UVなどを取り出すために使用する。
返り値($ver[]に入る)はコンポーネントなので以下のfilterExpandで中身を取り出す必要がある。
string $verE[] = `filterExpand -selectionMask 31 $ver`; $verの中から頂点(31で表される)を配列に展開して$verE[]に代入。
for($i = 0; $i < 6; $i++) 以下のループを$iが0から5まで6回実行する。
0から5番目の頂点(シリンダーの底にある頂点)を乱数によって移動する。
- select -r $verE[$i]; $i番目の頂点(シリンダーの底にある頂点)をセレクトする。
- $x = rand(-0.2, 0.2); 乱数の値(-0.2から0.2)を$xに代入。
- $z = rand(-0.2, 0.2); 乱数の値(-0.2から0.2)を$zに代入。
- move -r $x 0 $z; セレクトされている頂点を、その位置から$x, 0.0, $zだけ移動する。
  Y方向には移動しないことに注意。
for($i = 6; $i < 12; $i++) 以下のループを$iが6から11まで6回実行する。
6から11番目の頂点(シリンダーの天井にある頂点)を乱数によって移動する。
- select -r $verE[$i]; $i番目の頂点(シリンダーの天井にある頂点)をセレクトする。
- $y = rand(-0.3, 0.3); 乱数の値(-0.3から0.3)を$yに代入。
- move -r 0 $y 0; セレクトされている頂点を、その位置から0.0, $y, 0.0だけ移動する。
  X, Z方向には移動しないことに注意。
select -r $verE[13]; 13番目の頂点(シリンダーの天井の中心にある頂点)をセレクトする。
$y = rand(0.5, 1.0); 乱数の値(0.5から1.0)を$yに代入。
move -r 0 $y 0; セレクトされている頂点を、その位置から0.0, $y, 0.0だけ移動する。
X, Z方向には移動しないことに注意。

練習

上の makeRock7.melを参考にしてmakeRock8.melを作り、岩・石の個数と大きさ(スケール)を変更できるようにしてみよう。
- プロシージャーの名前と引数
  makeRock8(個数, スケールの最小値, スケールの最大値)
- (使用例)
  makeRock8.melを読み込んで、makeRock8(5, 2.0, 3.0)と実行すると5個の岩石が、X, Y, Z方向に2.0から3.0までの範囲でランダムにスケールされ、X, Z方向に-10.0から10までの範囲にランダムな位置に作られる。
- (ヒント)
  1. プロシージャの名前を書き換えて、プロシージャの引数を書く。
    makeRock8(int ..., float ..., float ...)
  2. プロシージャの内部をfor文で個数分だけ繰り返し実行するようにする。
    makeRock8(...) { for(...) { ........ } }
  3. シリンダーを作ったすぐ後で、乱数(rand)を使用してX, Z方向に移動(move)する。
  4. 外側のfor文の最後で乱数(rand)によってX, Y, Z方向にスケール(scale)をかける。
    その時、scaleの前で$poly[0]をselectしておく。

参考

練習課題

Prev | Next
Home | Contents

abe@injapan.net