アトリビュート
アトリビュートとは
MAYA に存在するオブジェクト(ノード)にはアトリビュートがついていて、
このアトリビュートの値を設定・変更することによってモデリング・アニメーション・レンダリングなどができるようになっています。
つまり、Maya 上で行なわれる多くの操作はアトリビュートに関する操作なので
MEL においてもアトリビュートの扱いは重要です。
MEL でアトリビュートにアクセスする場合は
ノード名とアトリビュート名が必要です。
アクセスする時はノード名とアトリビュート名の間を . (ピリオド)ではさみます。
例えば、camera1.tx などのように使用します。
アトリビュートには長い名前と短い名前がついているものがありますが、
その場合はどちらでもアクセスできます。
例えば、NURBS の球を作成すると作られる nurbsSphere1 などのトランスフォームノードの X 方向の移動値を表す translate X には以下のどちらの名前でもアクセスすることができます。
- nurbsSphere1.translateX (長い名前)
- nurbsSphere1.tx (短い名前)
アトリビュートの種類についてはアトリビュートのデータタイプの表を参照してください。
Mayaの内部構造
MAYA において GUI・MEL などを使ってモデリング・アニメーション・シェーディングなどの操作を行なうと以下の操作の全部、または一部が実行されます。
- ノードの作成
- ノードのアトリビュートに値を設定
- ノード同士のアトリビュートを接続
MAYA は、この 3 種のノードとアトリビュートに関する操作だけでモデリング・アニメーション・シェーディングを行なう非常にシンプルなシステムです。
しかし、これだけでは非効率なので、効率良く便利に操作するために GUI のメニューなどや MEL のコマンドが作られています。
アトリビュートを扱うためのコマンド
アトリビュートをあつかうためのコマンドには以下のようなものがあります。
- getAttr ノード名.アトリビュート名
- アトリビュートの値を得ます。
詳しい解説は「アトリビュートの値の取得」を参照してください。
- setAttr ノード名.アトリビュート名 アトリビュートの値
- アトリビュートの設定します。
詳しい解説は「アトリビュートの値の設定」を参照してください。
- listAttr ノード名
- ノードに存在するアトリビュート名をリスト表示します。
- connectAttr ノード名1.アトリビュート名1 ノード名2.アトリビュート名2
- アトリビュートの接続をします。
ノード 1 のアトリビュート 1 をノード 2 のアトリビュート 2 に接続します。
- disconnectAttr ノード名1.アトリビュート名1 ノード名2.アトリビュート名2
- アトリビュートの接続を切り離します。
ノード 2 のアトリビュート 2 に接続されているノード 1 のアトリビュート 1 を切り離します。
- aliasAttr アトリビュート別名 ノード名.アトリビュート名
- アトリビュートに別名をつけます。
別名をつけても元の名前もそのまま使えます。
また、別名はひとつしか付けられないので、
すでに別名が付けられているアトリビュート名に新しく別名を付けると古い別名は無くなります。
- aliasAttr -remove ノード名.アトリビュート別名
- アトリビュートの別名を取り消します。
または、以下のように元のアトリビュート名でも取り消すことができます。
aliasAttr -remove ノード名.アトリビュート名
- addAttr -longName 長いアトリビュート名 -shortName 短いアトリビュート名 -dt データ型 -at アトリビュート型 -min 最小値 -max 最大値 ノード名
- ダイナミックアトリビュートを追加します。
ノードにダイナミックアトリビュートを追加したい時に使用します。
このコマンドを使用する場合は、最低限「長いアトリビュート名」か「短いアトリビュート名」が必要です。
「データ型」「アトリビュート型」についてはアトリビュートのデータタイプの表を参照してください。
- deleteAttr ノード名.アトリビュート名
- ダイナミックアトリビュートを削除します。
元からあるアトリビュート、例えば NURBS の球を作成した時に作られるトランスフォームノードの translateX などは削除できません。
以下の例では getAttr コマンドによってアトリビュートの値を得て、変数に代入する方法を解説します。
- ノード名 nurbsSphere1 のアトリビュート translateX (省略した名前は tx)を、変数に代入したい時は以下のように実行します。
float $tx = `getAttr nurbsSphere1.tx`;
- ある string (文字列)の変数に名前が代入されているノードのアトリビュートを、他の変数に代入する時は以下のように実行します。
$変数名 = `getAttr $変数名.アトリビュート名`;
または、
$変数名 = `getAttr ($変数名 + ".アトリビュート名")`;
これらは場合によって使い分けます。
以下のコマンドはノード名 nurbsSphere1 のアトリビュート translateY (tx) の値を、変数 $ty に代入するものです。
string $name = "nurbsSphere1";
float $ty = `getAtrr $name.ty`;
- sphere コマンドなどで作られたノードの名前を変数に代入し、
そのノードのアトリビュートを得たい場合は以下のように実行します。
string $sname[] = `sphere`;
float $tz = `getAttr ($sname[0] + ".tz")`;
この場合、
float $tz = `getAttr $sname[0].tz`;
ではエラーになることに注意してください。
Tips
あるノードの複数のアトリビュートの値を得たい場合には、以下のように最初にノードを選択しておくと、ノード名を省略することができます。
select nurbsSphere1;
getAttr .tx;
getAttr .ty;
getAttr .tz;
以下の例では setAttr コマンドによってアトリビュートの値を設定する方法を解説します。
- ノード名 nurbsSphere1 のアトリビュート translateX (省略した名前は tx)に値(2.5)を設定したい場合は以下のように実行します。
setAttr nurbsSphere1.tx 2.5;
- ある string (文字列)の変数に名前が代入されているノードのアトリビュートに値を設定する場合は以下のように実行します。
string $name = "nurbsSphere1";
setAttr ($name + ".tx") 2.5;
- sphere コマンドなどで作られたノードの名前を変数に代入し、
そのノードのアトリビュートに値を設定したい場合は以下のように実行します。
string $sname[] = `sphere`;
setAttr ($sname[0] + ".ty") 2.5;
この場合、
setAttr $sname[0].ty 2.5;
ではエラーになることに注意してください。
Tips
あるノードの複数のアトリビュートに値を設定したい場合には、以下のように最初にノードを選択しておくと、ノード名を省略することができます。
select nurbsSphere1;
setAttr .tx 2.5;
setAttr .ty 3.0;
setAttr .tz 5.2;
アトリビュートの例
アトリビュートに値を設定する方法によって、球を螺旋上に並べる MEL スクリプトを作ってみましょう。
- 以下の MEL スクリプトを spiralObjects1.mel という名前で作ります。
global proc spiralObjects1(float $rad, int $num)
{
int $i;
float $r = 0.0;
float $y = 0.0;
string $name[];
for($i = 0; $i < $num; $i++)
{
$name = `sphere`;
setAttr ($name[0] + ".tx") $rad;
rotate -ws -p 0 0 0 0 $r 0;
setAttr ($name[0] + ".ty") $y;
$r += 30.0;
$y += 0.5;
}
}
- Script Editor の → によって spiralObjects1.mel を読み込みます。
- Script Editor のインプットウインドウに spiralObjects1(5.0, 30) と打ち込んで実行します。
- 半径 5 の螺旋状に球が 30 個並びます。
スクリプトの解説
global proc spiralObjects1(float $rad, int $num)
- 引数として $rad (円の半径の値)と $num (球の個数)をとるプロシージャーの宣言です。
int $i;
- for 文のカウンタとして使うための変数の宣言です。
float $r = 0.0;
- 球の回転角度を入れておく変数の宣言です。
float $y = 0.0;
- 球の高さ(translateY)を入れておく変数の宣言です。
string $name[];
- 球の名前を入れておくための string (文字列)の配列の宣言です。
for($i = 0; $i < $num; $i++)
- $num 回 for ループを実行します。
以下は for ループ内の処理の解説です。
$name = `sphere`;
- NURBS の球を作成し、その時作られるノードの名前を配列 $name に代入します。
作られるノードは複数(この場合は 2 個)なので、配列にしておく必要があることに注意してください。
球の名前を $name に代入するためにアサインを使用しています。
この時、配列 $name には以下のように代入されます。
- $names[0] にはトランスフォームノードの名前(nurbsSphere1など)
- $names[1] には球を作るインプットノードの名前(makeNurbsSphere1など)
setAttr ($name[0] + ".tx") $rad;
- $name[0] (球のトランスフォームノード)のアトリビュート(tx)に値 $rad を設定します。
(move $rad 0 0 と結果は同じになります)
このコマンドは以下のような順番で実行されます。
- まず $name[0] の部分が球の名前を表す文字列になります。
例えば "nurbsSphere1" になるとします。
- ($name[0] + ".tx") の括弧の中が
"nurbsSphere1" + ".tx"
と展開されて文字列を連結する演算子 + によって
"nurbsSphere1.tx"
という一つの文字列になります。
(MEL では + は複数の文字列を一つにまとめる演算子にもなります)
- 最終的に
setAttr nurbsSphere1.tx $rad;
が実行されます。
rotate -ws -p 0 0 0 0 $r 0;
- 移動された球をワールドスペース内で(0, 0, 0)を中心として Y軸周りに $r だけ回転します。
各フラグの意味は以下の通り。
- -ws
- ワールドスペースで回転させます。
- -p 0 0 0
- 回転の中心は(0, 0, 0)
- 0 $r 0
- X 軸周りに 0 度、Y 軸周りに $r 度、Z 軸周りに 0 度回転させます。
setAttr ($name[0] + ".ty") $y;
- $name[0] (球のトランスフォームノード)のアトリビュート(ty)に $y を設定します。
(move -r 0 $y 0 と結果は同じになります)
$r += 30.0;
- 球の回転角度に30.0を加えます。
$y += 0.5;
- 球の translateY の値に0.5を加えます。
練習
- 上の spiralObjects1.mel を参考にしてプロシージャーの引数を一つ増やし translateY の増減値を、
引数 $iy で変更できる MELスクリプトを spiralObjects2.mel という名前で作ってみましょう。
spiralObjects2(float $rad, int $num, float $iy)
spiralObjects2(5.0, 30, 0.2) の結果
- spiralObjects2.mel を改良して spiralObjects3.mel を作り、球(sphere)の代わりに circle を使用してチューブになるようにしてみましょう。
spiralObjects3(float $rad, int $num, float $iy)
(ヒント)
最期に select -all; と loft; を実行します。
spiralObjects3(5.0, 30, 0.4) の結果
まとめ
- MAYA ではノードのアトリビュートを設定・コネクトすることによって、モデリング・アニメーション・レンダリングを行います。
- アトリビュートの取得には getAttr 、設定には setAttr コマンドを使用します。
練習課題
参考
Prev | Next
Home | Contents
Mail