クイック・リファレンス

MEL コマンドの種類

シーンコマンド: もっとも良く使われるコマンドで 500 種類くらいがあります。シーンとその環境を操作するために使われます。
アドミニストレーションコマンド: ファイルの入出力や OS へのアクセスに使用されます。
ユーザーインターフェースコマンド: ボタン、ウインドウ、メニューなどの作成・制御に使います。
関数: 動きや、パーティクルの位置、その他の特別な効果を作るために使われます。
配列、カーブ、数学関数、乱数、色変換などの機能をもつ関数があります。

MEL コマンドの実行方法

Script Editor ( Window → General Editors → Scripte Editor )
Script Editor のインプットウインドウにコマンドを入力して Edit → Excute で実行します。
または、テンキーにあるエンターキーまたは、Ctrl + s によって実行します。
コマンドライン
MAYA ウインドウの下にあるコマンドラインにコマンドを入力して実行します。
コマンドシェル( Window → General Editors → Command Shell )
1 つづつコマンドを実行する Command Shell で実行します。
スクリプトファイル
エディターなどで作った MEL スクリプトを Script Editor などで読み込んで実行します。
source コマンドで MEL スクリプトを読んで実行することもできます。
シェルフアイコン
スクリプトをシェルフアイコンに登録して実行します。
ホットキー
スクリプトをホットキーに割り当てて実行します。
エクスプレッション
アトリビュートが設定・削除されたときや、オブジェクトなどが作られたり、消されたりした時に実行します。他の場合と違って Undo がききません。
スクリプトノード ( scriptNode コマンド)
スクリプトノードに登録したコマンドを実行します。

コメントは2種類あります。

//
行末までがコメント( C++ 風 )
/* */
入れ子にはできない( C言語風 )

変数の型

matrix 以外は配列にすることができます。

int: 整数
float: 浮動小数点数
string: 文字列
vector: ベクトル
matrix: 2 次元配列

ノードの種類

シェイプノード: 形状を定義
トランスフォームノード: 移動・回転・スケールなどを定義
インプットノード: オブジェクトのジオメトリなどを作成・変形するためのノード

ノード関係のコマンド

createNode: ノードを作成します。
shadingNode: ノードを作成します。シェーダ・テクスチャ・ライト・ポストプロセス・ユーティリティなどのノードを作成します。
listNodeTypes: ノードの種類をリストアップします。
nodeType: ノードの種類を返します。
nodePreset: ノードの現在のアトリビュートの値をファイルに保存します。
setNodeTypeFlag: ノードの現在のアトリビュートの値をファイルに保存します。
selectedNodes: セレクトされているノードのリストを返します。

アトリビュートの種類

Static: ノードに固有で削除できないもの
Dynamic: 追加・削除できるもの
Custom: ユーザが定義できて追加・削除できるもの

アトリビュー関係のコマンド

listAttr
アトリビュートの表示
getAttr
アトリビュートの取得
setAttr
アトリビュートの設定
connectAttr
アトリビュートの接続
disconnectAttr
アトリビュートの接続解除
aliasAttr
アトリビュートの別名定義
addAttr
アトリビュートの別名追加
deleteAttr
アトリビュートの別名削除

実行例

キーフレーム可能なアトリビュートを表示
listAttr -k nurbsSphere1;
アトリビュートを取得する
getAttr nurbsSphere1.ty;
アトリビュートを設定する
setAttr nurbsSphere1.ty 2.0;
string $obj = "nurbsSphere1";
setAttr ($obj + ".tz") 3.5;
select nurbsSphere1;
setAttr .tx 1.5; // セレクトされているノードの名前は省略可能
nurbsSphere1 の sy を nurbsSphere2 の sy に接続
connectAttr nurbsSphere1.sy nurbsSphere2.sy;
nurbsSphere1 の sy を nurbsSphere2 の sy に強制的に接続
元々 nurbsSphere2 の sy に接続していたアトリビュートは接続を解除されます。
connectAttr -f nurbsSphere1.sy nurbsSphere2.sy;
nurbsSphere1 の sy と nurbsSphere2 の sy の接続を解除
disconnectAttr nurbsSphere1.sy nurbsSphere2.sy;
nurbsSphere1 の ty を up という名前で別名定義
aliasAttr up nurbsSphere1.ty;
nurbsSphere1 の別名定義を取消す
aliasAttr -remove nurbsSphere1.ty;
または
aliasAttr -remove nurbsSphere1.up;
nurbsSphere1 にアトリビュートを追加
addAttr -longName "otherAngle" -shortName "oa" -min 0.001 -max 90 nurbsSphere1;

制御構造の種類


int $x = 3;
if($x > 1)
{
	print ("$x is greater than 1\n");
}
string $s = "test";
if($s == "test")
{
	print ("$s is test\n");
}

switch
変数と値は同じ型である必要があります。


int $x = 2;
switch($x)
{
	case 1 :
		print "$x is 1\n";
		break;
	case 2 :
		print "$x is 2\n";
		break;
	default :
		print "x is not 1 or 2\n";
}
string $s = "test1";
switch($s)
{
	case "test1" :
		print "$s is test1\n";
		break;
	case "test2" :
		print "$s is test2\n";
		break;
	default :
		print "x is not test1 or test2\n";
}

while


int $i = 0;
while($i < 3)
{
	print ($i + "\n");
	$i++;
}

do while


int $i = 0;
do
{
	print ($i + "\n");
	$i++;
} while($i < 3)

for


int $i;
for($i = 0; $i < 3; $i++)
{
	print ($i + "\n");
}


string $str[3] = { "aaa", "bbb", "ccc" };
for( $val in $str)
{
	print($val + "\n");
}

基本的なプリミティブ

cone
- cone ( NURBS )
- polyCone
cube
- nurbsCube ( NURBS )
- polyCube
curve
- curve ( NURBS )
cylinder
- cylinder ( NURBS )
- polyCylinder
plane
- nurbsPlane ( NURBS )
- polyPlane
polygon
- polyCreateFacet
sphere
- sphere ( NURBS )
- polySphere
torus
- torus ( NURBS )
- polyTorus

キーフレームアニメーションの手順

currentTime で現在の時間を設定
オブジェクトのアトリビュートを変更
setKeyframe でキーフレームを決定

パスアニメーションの手順

アニメートされるオブジェクトをセレクト
パスとなるカーブをセレクト
pathAnimation コマンドでパスアニメーション作成


select nurbsSphere1;
select -tgl curve1;
pathAnimation -startTimeU 0 -endTimeU 300;

ライトの種類

環境光 ( ambientLight )
平行光源 ( directionalLight )
スポットライト ( spotLight )
点光源 ( pointLight )
面光源 (defaultAreaLight)

返り値の受け取り方

バッククォート
string $a[] = `sphere -r 5`;
プロシージャとして実行
string $a[] = sphere(-r,5);
eval
string $com = "shpere";
string $a[] = `eval($com + "-r 5")`;

手続きの形


[global] proc [返り値の型] <手続きの名前>( [引数, ...] )
{
	[MEL文]
	[return 返り値;]
}

プロシージャを作る時の注意

同じ名前のプロシージャがあれば、後に定義された方が有効になります。
すでにあるコマンドと同じ名前のプロシージャを作ると、コマンドがプロシージャと入れ替わってしまいます。

MEL によるカスタマイズ

ホットキー
MEL のコマンドを Options → Customize UI → Hotkeys によって特定のキーに割り当てることができます。
複数のコマンドを割り当てることもできます。
nameCommand コマンドと hotkey コマンドによってもホットキーに割り当てることができます。 nameCommand -annotation "Make Sphere and Move" -command "sphere; move 1 2 3;" makeSphereAndMoveCommand; hotkey -k "c" -ctl -name makeSphereAndMoveCommand; // Ctrl + c キーにホットキーを登録
シェルフアイコン
MEL コマンドをアイコンに割り当てることができます。
1. Script Editor にコマンドを打ち込みます。
2. それらのコマンドをハイライトにします。
3. ハイライトにした部分を、マウスの中ボタンでシェルフにドラッグアンドドロップします。
4. すると新しいアイコンができて、コマンドが割り当てられます。
アイコンにはデフォールトのものが使われるので、独自のものを使用したい時には Options → Customize UI → Shelves で変更します。
アイコンの画像の解像度は 32 x 32 ピクセル、画像フォーマットは XPM です。
MAYA 起動時のセットアップ
スクリプトパスにある userSetup.mel というスクリプトが MAYA 起動時に実行されます。このスクリプトの中に自分用のユーザーインターフェイスの設定などを書いておきます。ただし、この中にシーンコマンドを書いておいても起動時に全てのオブジェクトなどがクリアーされるので書いておいても無駄です。
スクリプトパスは以下のコマンドで調べることができます。
internalVar -usd;

変数の型変換表

	変換される型
	int	float	string	vector	matrix
int	OK	OK	OK	<<$i, $i, $i>>	NONE
float	整数部分	OK	OK	<<$f, $f, $f>>	NONE
string	整数部分(数字でなければ0)	OK(数字でなければ0)	OK	OK(vectorかfloatでなければ0)	NONE
vector	ベクトルの長さの整数部分	ベクトルの長さ	3つのfloat	OK	OK([1][3]のみ)
matrix	ベクトルの長さの整数部分([1][3]より小さい時)	ベクトルの長さ([1][3]より小さい時)	NONE	OK([1][3]より小さい時)	OK

true, yes は 1, false, no は 0 になります。

ベクトルの演算子

+, +=: プラス
-, -=: マイナス
*, *=: int, floatとのはスカラー積、ベクトル同士は内積
/, /=: 除算
%, %=: 剰余
^, ^=: 外積
||, &&, !: 論理演算子
==, !=, >, <, >=, <=: 関係演算子

マトリクスの演算子

+, +=: プラス
-, -=: マイナス
*, *=: 乗算

レンダリングのパラメータ

レンダリングの種類
- ソフトウェアレンダリング
- ハードウェアレンダリング
- ベクタレンダリング
- mentalray
解像度
render -x x方向の解像度 -y y方向の解像度
によって指定する。

出力される画像のフォーマット
renderGlobals のアトリビュート imageFormat によって指定します。
imageFormat のとる値は以下の通りです。

値	フォーマット	拡張子	注意
1	SoftImage	.pic	*
2	WaveFront	.rla	*
3	TIFF	.tif	*
4	TIFF16	.tif	*
5	SGI	.sgi	*
6	Alias	.als	*
7	MAYA	.iff	デフォールト
8	JPEG	.jpg	*
9	PostScript	.eps	*
10	MAYA 16	.iff	*
11	Codak Cineon	.cin	*
12	Abekas NTSC or PAL	.yuv	*

デフォールトでは defaultRenderGlobals が rednerGlobals として存在しています。

クオリティ
renderQualityNode のアトリビュートによって設定します。

ウインドウの構成要素

Windows
windowコマンドによって作られます。
-visible オプションをtrueにするか、showWindowで表示することができます。
Controls
ボタン、チェックボックス、ラジオボタン、アイコン、フィールド、スライダーなどのウインドウを構成する、部品となるものです。
Layouts
GUI の要素(ボタン・レイアウトなど)をどのように並べるか(レイアウト)するかを決めるものです。
Groups
GUI の要素(ボタン・レイアウトなど)をまとめてグループ化するものです。
Menus
メニューとポップアップメニューです。
Collections
radioCollection などのトグルボタンを作ります。

Controls の一覧

Widget

button


window;
columnLayout;
button;
showWindow;

checkBox


window;
columnLayout;
checkBox -label "check1";
checkBox -label "check2";
checkBox -label "check3";
showWindow;

channelBox


window;
paneLayout;
channelBox;
showWindow;

iconTextButton


window;
columnLayout -adj true;
iconTextButton -style "iconOnly" -image1 "sphere.xpm" -label "sphere";
iconTextButton -style "iconAndTextHorizontal" -image1 "cone.xpm" -label "cone";
iconTextButton -style "iconAndTextVertical" -image1 "cube.xpm" -label "cube";
showWindow;

helpLine


window;
columnLayout -adj true;
text -label "help line";
helpLine;
showWindow;

iconTextCheckBox


window;
columnLayout -adj true;
iconTextCheckBox -style "iconOnly" -image1 "sphere.xpm" -label "sphere";                            
iconTextCheckBox -style "iconAndTextHorizontal" -image1 "cone.xpm" -label "cone";                                      
iconTextCheckBox -style "iconAndTextVertical" -image1 "cube.xpm" -label "cube";                                      
showWindow;

iconTextRadioButton


window;
columnLayout -adj true;
iconTextRadioCollection sampleIconTextRadioCollection;
iconTextRadioButton -st "iconOnly" -i1 "sphere.xpm" -l "sphere" -select;
iconTextRadioButton -st "iconAndTextHorizontal" -i1 "cone.xpm" -l "cone";
iconTextRadioButton -st "iconAndTextVertical" -i1 "cube.xpm" -l "cube";
showWindow;

nodeIconButton


window;                                                   
columnLayout -adj true;                                         
nodeIconButton -style "iconOnly" -command "torus" -image1 "torus.xpm";
nodeIconButton -style "iconAndTextHorizontal" -command "directionalLight" -image1 "directionallight.xpm" -label "directional Light";
showWindow;

radioButton


window;
columnLayout;
radioCollection;                                                       
radioButton -label "button1" -select;                             
radioButton -label "button2";                           
radioButton -label "button3";                            
showWindow;

Ramp


string $ramp = `createNode ramp`;
window;
columnLayout;
rampColorPort -node $ramp;
showWindow;

separator


window;
columnLayout -adj true;
text -label "-style default";
separator;                                                         
text -label "-style none";
separator -style "none";
text -label "-style single";
separator -style "single";
text -label "-style double";
separator -height 10 -style "double";
text -label "-style singleDash";
separator -height 10 -style "singleDash";
text -label "-style doubleDash";
separator -height 40 -style "doubleDash";
text -label "-style in";
separator -height 40 -style "in";
text -label "-style out";
separator -height 40 -style "out";
showWindow;

shelfButton


window;
columnLayout;
shelfLayout;
shelfButton -annotation "sphere" -image1 "sphere.xpm" -command "sphere";
shelfButton -annotation "cone" -image1 "cone.xpm" -command "cone";
showWindow;

symbolButton


window;
columnLayout;
symbolButton -image "sphere.xpm";
symbolButton -image "cube.xpm";
showWindow;

symbolCheckBox


window;
columnLayout;
symbolCheckBox -image "sphere.xpm";
symbolCheckBox -image "cube.xpm";
showWindow;

swatchDisplayPort


window;
columnLayout;
string $shname = `shadingNode -asShader lambert`;
swatchDisplayPort -wh 64 64 -sn $shname;
attrColorSliderGrp -at ($shname + ".color");
showWindow ;

text


window;
columnLayout;
text -label "text1";
text -label "text2";
showWindow;

textScrollList


window;
paneLayout;
textScrollList -allowMultiSelection true
	-append "test1"
	-append "test2"
	-append "test3"
	-append "test4"
	-append "test5"
	-append "test6"
	-selectItem "test2"
	-showIndexedItem 4;
showWindow;

toolButton


window;
columnLayout;
toolCollection;                                                        
toolButton                                                             
	-tool selectSuperContext
	-toolImage1 selectSuperContext "aselect.xpm";
toolButton                                                             
	-tool moveSuperContext
	-toolImage1 moveSuperContext "move_M.xpm";
toolButton                                                             
	-tool scaleSuperContext
	-toolImage1 scaleSuperContext  "scale_M.xpm";
showWindow;

Slider

floatSlider


window;
columnLayout -adj true;
floatSlider;
showWindow;

floatSliderGrp


window;
columnLayout -adj true;
floatSliderGrp -field true -min 0.0 -max 10.0 -value 2.0;
showWindow;

floatScrollBar


window;
columnLayout -adj true;
floatScrollBar;
showWindow;

intSlider


window;
columnLayout -adj true;
intSlider;
showWindow;

intSliderGrp


window;
columnLayout -adj true;
intSliderGrp -field true -min 0 -max 10 -value 2;
showWindow;

intScrollBar


window;
columnLayout -adj true;
intScrollBar;
showWindow;

colorSliderGrp


window;
columnLayout;
colorSliderGrp -label "Color" -rgb 1 0 0;
showWindow;

colorIndexSliderGrp


window;
columnLayout;
colorIndexSliderGrp -label "Indexed Color" -min 1 -max 31 -value 1;
showWindow;

colorSliderButtonGrp


window;
columnLayout;
colorSliderButtonGrp
	-label "Label"
	-buttonLabel "button"
	-buttonCommand "sphere"
	-rgb 1 0 0
	-symbolButtonDisplay true
	-columnWidth 5 25
	-image "navButtonUnconnected.xpm";
showWindow;

Field

floatField


window;
columnLayout -adj true;
floatField;
showWindow;

intField


window;
columnLayout -adj true;
intField;
showWindow;

nameField


window;
columnLayout -adj true;
string $sname[] = `sphere`;
nameField -object $sname[0];
showWindow;

scrollField


window;
columnLayout -adj true;
scrollField -text "scrollField";
showWindow;

shellField


window;
columnLayout -adj true;
shellField;
showWindow;

textField


window;
columnLayout -adj true;
textField;
showWindow;

textFieldButtonGrp


window;
columnLayout;
textFieldButtonGrp -label "Label" -text "textFieldButtonGrp" -buttonLabel "Button";
showWindow;

menu


window -menuBar true -width 150;
menu -label "Menu" -tearOff true;
	menuItem -label "menu1";
	menuItem -label "menu2";
	menuItem -label "menu3";
	menuItem -divider true;
	menuItem -label "menu4";
menu -label "Help" -helpMenu true;
	menuItem -label "help";
columnLayout;
button;
showWindow;

optionMenu


window;
columnLayout;
optionMenu -label "Menu";
	menuItem -label "test1";
	menuItem -label "test2";
	menuItem -label "test3";
showWindow;

popupMenu


window;
columnLayout;
button;
popupMenu;
menuItem -label "test1";
menuItem -label "test2";
menuItem -label "test3";
showWindow;

Layoutの一覧

columnLayout
部品を縦に並べる。


window;
columnLayout;
button;
button;
button;
showWindow;

formLayout
部品を絶対位置、相対位置で自由に並べることができる。


window;
	string $form = `formLayout -numberOfDivisions 100`;
	string $b1 = `button -label "button1"`;
	string $b2 = `button -label "button2"`;
	string $b3 = `button -label "button3"`;
	string $b4 = `button -label "button4"`;

	formLayout -edit
	-attachForm     $b1	"top"	5
	-attachForm     $b1	"left"	5
	-attachControl  $b1	"bottom" 15 $b2
	-attachPosition $b1	"right"	0 55

	-attachNone     $b2	"top"
	-attachForm     $b2	"left"	10
	-attachForm     $b2	"bottom" 10
	-attachForm     $b2	"right"	10

	-attachForm     $b3	"top"	5
	-attachPosition $b3	"left"	0 70
	-attachControl  $b3	"bottom" 25 $b4
	-attachForm     $b3	"right"	5

	-attachNone     $b4	"top"
	-attachPosition $b4	"left"	0 60
	-attachControl  $b4	"bottom" 35 $b2
	-attachForm     $b4	"right"	5

	$form;

showWindow;

frameLayout
子どもの部品に枠を付けて表示する。


window;
columnLayout -adjustableColumn true;
frameLayout -label "Frame1" -labelAlign "top" -borderStyle "in";
	columnLayout;
	button;
	button;
	setParent ..;
setParent ..;
frameLayout -label "Frame2" -labelAlign "center" -borderStyle "out";
	columnLayout;
	button;
	button;
	setParent ..;
setParent ..;
frameLayout -label "Frame3" -labelAlign "center" -borderStyle "etchedIn";
columnLayout;
	button;
	button;
	setParent ..;
setParent ..;
frameLayout -label "Frame4" -labelAlign "bottom" -borderStyle "etchedOut";
columnLayout;
	button;
	button;
	setParent ..;
setParent ..;
showWindow;

gridLayout
部品を縦・横に並べる。


window;
gridLayout -numberOfColumns 3 -cellWidthHeight 50 30;
button;
button;
button;
button;
button;
showWindow;

menuBarLayout
メニューバーを付けて表示する。


window;
columnLayout -adjustableColumn true;
menuBarLayout;
menu -label "File";
	menuItem -label "New";
	menuItem -label "Open";
	menuItem -label "Close";
menu -label "Help" -helpMenu true;
	menuItem -label "About...";
setParent ..;
button;
button;
showWindow;

paneLayout
ウインドウを分割して部品を表示する。


window;
paneLayout -configuration "quad";
button;
columnLayout;
button;
button;
setParent ..;
rowLayout -numberOfColumns 2 -columnWidth2 55 50;
button;
button;
setParent ..;
text -label "paneLayout";
showWindow;

rowColumnLayout
部品を縦・横に並べる。
各行・列の幅も変えることができる。


window;
rowColumnLayout -numberOfRows 3
	-rowHeight 1 30
	-rowHeight 2 50;
button;
button;
button;
button;
button;
button;
button;
showWindow;

rowLayout
部品を横に並べる。


window;
rowLayout -numberOfColumns 3 -columnWidth3 65 55 60;
button;
button;
button;
showWindow;

scrollLayout
スクロールバー付きで部品を表示する。


window;
scrollLayout -horizontalScrollBarThickness 16 -verticalScrollBarThickness 16;
columnLayout;
int $i;
for($i = 0; $i < 10; $i++)
{
	text -label ("label " + $i);
}
showWindow;

shelfLayout
シェルフを作る。


window;
shelfLayout;
iconTextButton -style "iconOnly" -image1 "sphere.xpm";
iconTextButton -style "iconOnly" -image1 "cone.xpm";
iconTextButton -style "iconOnly" -image1 "cube.xpm";
setParent ..;
showWindow;

shelfTabLayout
シェルフ・タブグループを作成・編集する。


window;
shelfTabLayout -image "smallTrash.xpm" -imageVisible true;
shelfLayout Shelf1;
setParent ..;
shelfLayout Shelf2;
setParent ..;
showWindow;

tabLayout
タブを作る。


window;
string $tabs = `tabLayout`;
	string $col1 = `columnLayout`;
	button;
setParent ..;
	string $col2 = `columnLayout`;
	button;
	button;
setParent ..;
tabLayout -edit -tabLabel $col1 "tab1" -tabLabel $col2 "tab2" $tabs;
showWindow;

コマンドを定義するためのオプション

-command
ボタンなどが押された時実行されるコマンドの定義
-changeCommand
スライダーなどで値が変化した時のコマンドを定義
-onCommand
チェックボックス、ラジオボタン、ツールボックスなどでチェックされた時に実行するコマンドの定義
-offCommand
チェックボックス、ラジオボタン、ツールボックスなどでチェックがはずされた時に実行するコマンドの定義
-enterCommand
テキストフィールドなどでEnterキーが押された時のコマンドを定義
-dragCommand
スライダーなどでマウスカーソルのドラッグによって値が変化した時のコマンドを定義

パネルの種類

hardwareRenderPanel


window;
paneLayout;
hardwareRenderPanel;
showWindow;

hyperPanel


window;
paneLayout;
hyperPanel;
showWindow;

modelEditor


window;
paneLayout;
modelEditor;
showWindow;

modelPanel


window;
paneLayout;
modelPanel;
showWindow;

nodeOutliner


string $sname[] = `sphere`;
window;
paneLayout;
nodeOutliner -showInputs true -a $sname[0];
showWindow;

outlinerPanel


window;
paneLayout;
outlinerPanel;
showWindow;

spreadSheetEditor


 
sphere;
window;
paneLayout;
spreadSheetEditor -mainListConnection `selectionConnection -activeList`;
showWindow;

scriptEditorPanel
以下のコマンドは、スクリプトエディタ以外で実行しないと、スクリプトエディタが表示されない。 (スクリプトエディタはひとつしか表示できないため) window; frameLayout -label "scriptEditor" scriptEditorFrameLayout; scriptedPanel -e -p scriptEditorFrameLayout scriptEditorPanel1; showWindow;

ダイアログの種類

colorEditor
RGB,HSVで色を編集します。
色の値を返します。
confirmDialog
押されたボタンの値を返すモーダルダイアログ
confirmDialog -message "Are you Ok ?" -button "Ok" -button "No" -defaultButton "Ok" -cancelButton "No" -dismissString "No";
fileDialog
ファイルを選択するためのダイアログ
選択されたファイル名を返します。

fileBrowserDialog
ファイルを選択するためのダイアログ
Windows 専用である。
[fileBrowserDialog]

fileBrowserDialog を表示するスクリプト


 
global proc int importMayaBinary( string $filename, string $fileType )
{
	print ($filename+"\n");
	print ($fileType+"\n");
	return 1;
}
fileBrowserDialog -m 0 -fc "importMayaBinary" -ft "mayaBinary" -an "MayaBinary";

promptDialog
テキストフィールド付のモーダルダイアログ
promptDialog -title "Prompt Dialog" -message "Are You Ok ?" -button "OK" -button "No" -defaultButton "OK" -cancelButton "No" -dismissString "No";

テキストの内容は promptDialog -q によって取り出すことができます。

layoutDialog
レイアウト可能なダイアログ
[layoutDialog]


 
global proc checkboxPrompt()
{
	string $form = `setParent -q`;
	formLayout -e -width 300 $form;
	string $t = `text -l "以下のいづれかのボタンを押してください"`;

	string $b1 = `button -l "Abort"    -c "layoutDialog -dismiss \"作成\""`;
	string $b2 = `button -l "Skip"     -c "layoutDialog -dismiss \"適用\""`;
	string $b3 = `button -l "Continue" -c "layoutDialog -dismiss \"中止\""`;

	string $cb1 = `checkBox -label "操作を覚えておく"`;

	int $spacer = 5;
	int $top = 5;
	int $edge = 5;

	formLayout -edit
	-attachForm            $t   "top"    $top
	-attachForm            $t   "left"   $edge
	-attachNone            $t   "bottom"
	-attachForm            $t   "right"  $edge

	-attachControl         $b1  "top"    $spacer $t
	-attachForm            $b1  "left"   $edge
	-attachNone            $b1  "bottom"
	-attachPosition        $b1  "right"  $spacer 33

	-attachControl         $b2  "top"    $spacer $t
	-attachPosition        $b2  "left"   $spacer 33
	-attachNone            $b2  "bottom"
	-attachPosition        $b2  "right"  $spacer 66

	-attachControl         $b3  "top"    $spacer $t
	-attachPosition        $b3  "left"   $spacer 66
	-attachNone            $b3  "bottom"
	-attachForm            $b3  "right"  $edge

	-attachControl         $cb1 "top"    $spacer $b1
	-attachForm            $cb1 "left"   $edge
	-attachForm            $cb1 "bottom" $spacer
	-attachNone            $cb1 "right"
	$form;
}
layoutDialog -ui "checkboxPrompt";

ブラウザ

Web ブラウザ


 
window;
columnLayout;
webBrowser -w 800 -h 600 -url "http://www.not-enough.org/abe/manual/";
showWindow;

ウインドウの管理

listUI
UIオブジェクトの表示
deleteUI
UIオブジェクトの削除

参考

リファレンス

Home | Contents

Mail